dotfiles/zsh/prompt

source "$DOTFILES_SHELL_DIR/prompt_segments"
source "$DOTFILES_ZSH_DIR/prompt_segments"

prompt_host() {
    if [[ $UID -eq 0 ]]; then
        prompt_segment red white '%n@%m'
    else
        prompt_segment black white '%n@%m'
    fi
}

prompt_dir() {
    prompt_segment green white '%~'
}

prompt_git() {
    if [[ -n $GIT_PS1_STATUS ]]; then
        PROMPT_VCS_TYPE='git'
        PROMPT_VCS_REF="$GIT_PS1_BRANCH"
        PROMPT_VCS_WPATH="$GIT_PS1_TOPLEVEL"
        PROMPT_VCS_WNAME="$GIT_PS1_NAME"
        PROMPT_VCS_WPWD="$GIT_PS1_PREFIX"
        [[ "$GIT_PS1_STATUS" == *t* ]] && PROMPT_VCS_DIRTY=1
        [[ "$GIT_PS1_STATUS" == *u* ]] && PROMPT_VCS_DIRTY=1
        [[ "$GIT_PS1_STATUS" == *s* ]] && PROMPT_VCS_DIRTY=1
        return 0
    else
        unset PROMPT_VCS_TYPE
        return 1
    fi
}

prompt_vcs_repo() {
    if prompt_git; then # TODO: || prompt_hg
        local branch_icon repo_color
        if prompt_is_fancy; then
            branch_icon=" $POWERLINE_BRANCH "
        else
            branch_icon=" ⎇ "
        fi

        if [[ $PROMPT_VCS_DIRTY -eq 1 ]]; then
            repo_color=red
        else
            repo_color=blue
        fi

        prompt_segment $repo_color white "$PROMPT_VCS_WNAME$branch_icon$PROMPT_VCS_REF"
        [[ -n $PROMPT_VCS_WPWD ]] && prompt_segment green white "$PROMPT_VCS_WPWD"

        return 0
    else
        return 1
    fi

}

prompt_vcs_status() {
    # status symbols
    if prompt_git; then
        local vcs_status=""
        [[ "$GIT_PS1_STATUS" == *h* ]] && vcs_status+="${NONE}↰"
        [[ "$GIT_PS1_STATUS" == *t* ]] && vcs_status+="${R}!"
        [[ "$GIT_PS1_STATUS" == *u* ]] && vcs_status+="${Y}≠"
        [[ "$GIT_PS1_STATUS" == *s* ]] && vcs_status+="${R}±"
        [[ "$GIT_PS1_STATUS" == *n* ]] && vcs_status+="${BB}∅"
        [[ -n "$vcs_status" ]] && prompt_segment black white "${vcs_status}"
    fi
}

prompt_vcs_action() {
    # action info
    if prompt_git; then
        local action=""
        [[ "$GIT_PS1_STATUS" == *R* ]] && action+=" rebase"
        [[ "$GIT_PS1_STATUS" == *i* ]] && action+="-i"
        [[ "$GIT_PS1_STATUS" == *A* ]] && action+=" apply"
        [[ "$GIT_PS1_STATUS" == *M* ]] && action+=" merge"
        [[ "$GIT_PS1_STATUS" == *B* ]] && action+=" bisect"
        [[ -n "$action" ]] && prompt_segment red white "$action"
    fi
}

prompt_segment_test() {
    prompt_segment red white
    prompt_segment default white
    prompt_segment blue white
    prompt_segment default white
    prompt_segment green white
    prompt_segment default white
    prompt_segment cyan white
    prompt_segment default white
    prompt_segment yellow white
    prompt_segment default white
    prompt_segment white black
    prompt_segment default white
    prompt_segment black white
    prompt_segment default white
    prompt_segment red white
    prompt_segment default white
    prompt_segment
    CURRENT_BG='NONE'
    echo
}

rprompt_segment_test() {
    rprompt_segment
    rprompt_segment red white
    rprompt_segment default white
    rprompt_segment blue white
    rprompt_segment default white
    rprompt_segment green white
    rprompt_segment default white
    rprompt_segment cyan white
    rprompt_segment default white
    rprompt_segment yellow white
    rprompt_segment default white
    rprompt_segment white black
    rprompt_segment default white
    rprompt_segment black white
    rprompt_segment default white
    rprompt_segment red white
    rprompt_segment default white
    CURRENT_BG='NONE'
    echo
}

prompt_last_rc() {
    #echo -n "%(?..%B[%?]%b)"
    [[ $LAST_CMD_RC -ne 0 ]] && prompt_segment red white "$LAST_CMD_RC"
}

prompt_vi_mode() {
    local mode_color mode_text

    PROMPT_VI_MODE="${${KEYMAP/vicmd/NORMAL}/(main|viins)/INSERT}"

    case $PROMPT_VI_MODE in
        NORMAL)
            mode_color='green'
            mode_text='N'
            ;;
        *)
            mode_color='blue'
            mode_text='I'
            ;;
    esac
    [[ -n $mode_color ]] && prompt_segment $mode_color white $mode_text
}

function zle-line-init zle-keymap-select {
    set_prompt
    zle reset-prompt
}
zle -N zle-line-init
zle -N zle-keymap-select

prompt_build() {
    RPROMPT_SEGMENTS=''
    prompt_setup_segments
    CURRENT_BG='NONE'
    prompt_host
    prompt_vcs_repo || prompt_dir
    prompt_end
    echo -n ' '
}

rprompt_build() {
    RPROMPT_SEGMENT=1
    prompt_setup_segments
    CURRENT_BG='NONE'
    prompt_last_rc
    prompt_vcs_status
    prompt_vcs_action
    rprompt_end
}

prompt_opts=(cr percent)

set_prompt() {
    __git_ps1_vars
    PROMPT="$(prompt_build)"
    RPROMPT="$(rprompt_build)"
}

# vim: ft=zsh